axe_shift=18.2;
shaft_distance=53;
module fork_shaft(){
    thread_height=38;
    thread_diameter=25.4;
    
    shaft_height1=110;
    shaft_diameter1=thread_diameter;
    
    shaft_height2=6;
    shaft_diameter2=27;    
    
    translate([0,0,-thread_height])
        cylinder(h=thread_height,d=thread_diameter);
        
    translate([0,0,-(thread_height+shaft_height1)])
        cylinder(h=shaft_height1,d=shaft_diameter1);
    
    translate([0,0,-(thread_height+shaft_height1+shaft_height2)])
        cylinder(h=shaft_height2,d=shaft_diameter2);

}

module forking(){
    for (side = [-1,1])
	hull() {
        translate([0,0,-34]) cylinder(d=39,h=34);
        translate([axe_shift, side * shaft_distance, -56]) cylinder(d=31.3, h=29);
    }    
    translate([0,0,-43]) cylinder(d=39,h=9);
}

module side_shaft(){
    
    translate([0,0,-38.5])cylinder(d=25.5,h=38.5);
    translate([0,0,-(38.5+14.8)]) cylinder(d1=41.5,d2=25.5,h=14.8);
    translate([0,0,-(38.5+22)]) cylinder(d1=32.5,d2=41.5,h=22-14.8);
    translate([0,0,-(38.5+184)]) cylinder(d1=32,d2=32.5,h=176);
}

module wheel_holder(){
    thick=4.5;
    rotate([270,90,0])
    translate([0,0,-thick/2])
    difference(){
        union(){        
            hull(){
                cylinder(d=32.5,h=thick);
                translate([-57.35,5.35,0])cube([35.3,35.3,thick]);
            }
            translate([0,0,1.9-thick])cylinder(d=25,h=thick);    
        }    
        translate([0,0,1.9])cylinder(d=25,h=thick);
        hull(){
            translate([0,0,-3])cylinder(d=10,h=15);
            translate([10,-5,-3])cube([10,10,15]);
        }
    }
}

module suspension_fork(depth=0) {
    // from top to bottom ...
    
    fork_shaft();
    translate([0,0,-154]) forking();
    // all following measuress are pure phantasy
    
    for (side=[-1,1]){
        translate([axe_shift,side * shaft_distance,-(210)]) side_shaft();
    }
    
    translate([45,shaft_distance,-460]) wheel_holder();
    mirror([0,1,0])translate([45,shaft_distance,-460]) wheel_holder();
}

function wheel_offset(depth=0) = depth - 510;

suspension_fork();