1 files changed, 35 insertions, 0 deletions
diff --git a/examples/example022.scad b/examples/example022.scad
new file mode 100644
index 0000000..ac8cb1c
--- /dev/null
+++ b/examples/example022.scad
@@ -0,0 +1,35 @@
+// size is a vector [w, h, d]
+module roundedBox(size, radius, sidesonly)
+{
+  rot = [ [0,0,0], [90,0,90], [90,90,0] ];
+  if (sidesonly) {
+    cube(size - [2*radius,0,0], true);
+    cube(size - [0,2*radius,0], true);
+    for (x = [radius-size[0]/2, -radius+size[0]/2],
+           y = [radius-size[1]/2, -radius+size[1]/2]) {
+      translate([x,y,0]) cylinder(r=radius, h=size[2], center=true);
+    }
+  }
+  else {
+    cube([size[0], size[1]-radius*2, size[2]-radius*2], center=true);
+    cube([size[0]-radius*2, size[1], size[2]-radius*2], center=true);
+    cube([size[0]-radius*2, size[1]-radius*2, size[2]], center=true);
+
+    for (axis = [0:2]) {
+      for (x = [radius-size[axis]/2, -radius+size[axis]/2],
+             y = [radius-size[(axis+1)%3]/2, -radius+size[(axis+1)%3]/2]) {
+        rotate(rot[axis]) 
+          translate([x,y,0]) 
+          cylinder(h=size[(axis+2)%3]-2*radius, r=radius, center=true);
+      }
+    }
+    for (x = [radius-size[0]/2, -radius+size[0]/2],
+           y = [radius-size[1]/2, -radius+size[1]/2],
+           z = [radius-size[2]/2, -radius+size[2]/2]) {
+      translate([x,y,z]) sphere(radius);
+    }
+  }
+}
+
+translate([-15,0,0])roundedBox([20,30,40], 5, true);
+translate([15,0,0]) roundedBox([20,30,40], 5, false);